! Path Coefficients Model
! BMI data in Australian twins
! Young and old female same-sex pairs
! Test of heterogeneity across age cohorts 
! Younger cohort 18-30 years of age
! Older cohort 31 or more years of age

#NGroups 6

G1: Model parameters for younger cohort females
Calculation_Group
Begin Matrices;
W LOwer 1 1 free    !nonadditive/dominance genetic effects
X LOwer 1 1 free     !additive genetic effects
Y LOwer 1 1                 !shared environmental effects
Z LOwer 1 1 free     !unique environmental effects
H FUll 1 1           
Q FUll 1 1
End Matrices:
Matrix H 
.5
Matrix Q
.25
Begin Algebra;
A = X*X' ;
D = W*W' ;
C = Y*Y' ;
E = Z*Z' ;
End Algebra;
Label Row W dom_gen_y     !labels for y=younger output
Label Row X add_gen_y       !note: only the G1-G2 labels differ
Label Row Y shr-env_y
Label Row Z uni-env_y
Label Row D dom_gen_y
Label Row A add_gen_y
Label Row C shr-env_y
Label Row E uni-env_y
Start .5 All      !3 x .5squared = .75, roughly Vp
End

G2: Model parameters for older cohort females 
Calculation_Group
Begin Matrices;
W LOwer 1 1 free     !nonadditive/dominance genetic effects
X LOwer 1 1 free      !additive genetic effects
Y LOwer 1 1                  !shared environmental effects
Z LOwer 1 1 free      !unique environmental effects
H FUll 1 1           
Q FUll 1 1
End Matrices:
Matrix H 
.5
Matrix Q
.25
Begin Algebra;
A = X*X' ;
D = W*W' ;
C = Y*Y' ;
E = Z*Z' ;
End Algebra;
Label Row W dom_gen_o   !labels for output for o=older cohort
Label Row X add_gen_o
Label Row Y shr-env_o
Label Row Z uni-env_o
Label Row D dom_gen_o
Label Row A add_gen_o
Label Row C shr-env_o
Label Row E uni-env_o
Start .5 All      !3 x .5squared = .75, roughly Vp
End

G3: young female MZ twin pairs
Data NInput_vars=2 NObservations=534
Labels bmi_t1 bmi-t2
CMatrix Symmetric
.7247 .5891 .7915
Matrices= Group 1                                 !select matrices from G1
Covariances A+C+D+E | A+C+D _    !exp cov for younger MZ twins
            A+C+D   | A+C+D+E /
Options RSidual
End 

G4: young female DZ twin pairs
Data NInput_vars=2 NObservations=328
Labels bmi_t1 bmi-t2
CMatrix Symmetric 
.7786 .2461 .8365
Matrices= Group 1                                                !select matrices from G1
Covariances A+C+D+E   | H@A+C+Q@D _   !exp cov for younger DZ twins
            H@A+C+Q@D | A+C+D+E /
Matrix H .5
Matrix Q .25
Start .6 All
Options RSidual NDecimals=4
End

G5: old female MZ twin pairs
Data NInput_vars=2 NObservations=637
Labels bmi_t1 bmi-t2
CMatrix Symmetric
.9759 .6656 .9544
Matrices= Group 2                                   !select matrices from G2
Covariances A+C+D+E | A+C+D _      !exp cov for older MZ twins
            A+C+D   | A+C+D+E /
Options RSidual
End 

G6: old female DZ twin pairs
Data NInput_vars=2 NObservations=380
Labels bmi_t1 bmi-t2
CMatrix Symmetric 
.9150 .3124 1.0420
Matrices= Group 2                                                !select matrices from G2
Covariances A+C+D+E   | H@A+C+Q@D _   !exp cov matrix for older DZ twins
            H@A+C+Q@D | A+C+D+E /
Matrix H .5
Matrix Q .25
Start .6 All
Options RSidual NDecimals=4
Options multiple issat
End

Save sat_model

!Equate paramters across younger and older cohorts
Equate W(1,1,1) W(2,1,1)
Equate X(1,1,1) X(2,1,1)
Equate Z(1,1,1) Z(2,1,1)
End

!ADE model for youger cohort; AE model for older cohort
Get sat_model
Drop 4
Interval A(1,1,1) D(1,1,1) E(1,1,1)
Interval A(2,1,1) D(2,1,1) E(2,1,1)
End